مناقشة مشاريع الدفعة التاسعة عشر لطلبة كلية الهندسة تاجوراء

اليوم تم مناقشة مشاريع تخرج طلبة قسمي الهندسة الميكانيكية و الالكترونية حيث تم مناقشة 10 مشاريع خمسة لكل قسم كان من ضمنها مشروع باشرافي و انجاز الطالب محمد صالح الطيب كان المشروع بعنوان

Finite Element Analysis and Optimization of Cantilever Beam for minimum weight

استخدام طريقة العناصر المتناهية و المفاضلة للحصول على اقل وزن لعارضة مثبته من احد اطرافها

ملخص المشروع: مع ازدياد شدة التنافس التجاري, تحاول المؤسسات الصناعية تخفيض تكاليف الانتاج و المواد الخام. ويمكن تحقيق هذا الهدف بإجاد الخيار الامثل لحجم وشكل القطعة. يجب تشجيع المصممين على استخدام طرق اتخاذ القرار مثل طرق المفاضلة (Optimization methods). و لهذا السبب فان طرق المفاضلة تم تطويرها لمساعدة المهندسين على تصميم منتجات تجمع بين الكفائة و الجدوي الاقتصادية.

 

في هذا البحث تم استخدام برنامج محاكاة بعرف باسم الانسس (ANSYS) لمحكاة نموذج دعامة مثبتة من طرف واحد و واقعة تحت تاثير قوة ثابتة عند الطرف الاخر. تم بناء النموذج باستخدام لغة برمجة خاصة تعرف بـ APDL وهي لغة برمجة تمكن من يناء النموذج بشكل يارامتري (يمكن تغيير بعض الابعاد في الشكل خلال المحاكاة) لمحاكاة دعامة مستطيلة المقطع و اجراء عملية المفاضلة عليها للحصول على اقل وزن ممكن لتحمل هذا الحمل.

تم التحقق من نتائج عملية المحاكاة لدعامة مستطيلة وذلك بمقارنتها بنتائج تحليلية لنفس الشكل و كانت النتائج متطابقة الى حد كبير حيث وصلت نسبة التوافق الى 97% في الاجهاد و 100% في الانحناء. الامر الذي يجعلنا نستخدم هذه الطريقة و بثقة في محاكاة مثل هذه المشاكل لتقليل الوزن. 

المادة التي استخدمت في المحاكاة هي الفولاذ (AISI 1018) و خصائصها متوفرة في المراجع. تم استخدام برنامج المفاضلة الموجود في الانسس بهدف تقليل وزن الدعامة بالتحكم في متغيرات التصميم (سمك وارتفاع الدعامة) و نتائج التصميم (الاجهاد). بشكل عام تعتبر متغيرات التصميم

the APDL (copy the text below and paste it in Ansys command windows)

! 3d shaft optimization
! GEOMETRY (Dimensions in meters)
*create,beam-384
/TITLE,3D Shaft optimization
/PREP7
H=.010 ! Height of the beam cross section
W=.005 ! Width of the beam cross section
L=.100 ! Length of the beam
L2=.01 ! the attached part to put the pressure load on it
! key points of the first side of the beam
K,1,0,0,0
K,2,L,0,0
K,3,L+L2,0,0
K,4,L+L2,H,0
K,5,L,H,0
K,6,0,H,0
! key points of the other side of the beam away from the first one by DISTANCE W= WIDTH OF THE BEAM
K,7,0,0,W
K,8,L,0,W
K,9,L+L2,0,W
K,10,L+L2,H,W
K,11,L,H,W
K,12,0,H,W
! draw the lines of the first side by joining the key points
LSTR, 1, 2
LSTR, 2, 3
LSTR, 3, 4
LSTR, 4, 5
LSTR, 5, 6
LSTR, 6, 1
LSTR, 5, 2
! draw the lines of second side by joining the key points
LSTR, 7, 8
LSTR, 8, 9
LSTR, 9, 10
LSTR, 10, 11
LSTR, 11, 12
LSTR, 12, 7
LSTR, 11, 8
! draw the lines to joine the first surface with the second one
LSTR, 1, 7
LSTR, 2, 8
LSTR, 3, 9
LSTR, 4, 10
LSTR, 5, 11
LSTR, 6, 12
! the othe vertical areas
AL,1,7,5,6
AL,2,3,4,7
AL,8,14,12,13
AL,9,10,11,14
! the top and bo
AL,3,17,10,18
AL,7,16,14,19
AL,6,15,13,20
AL,1,16,8,15
AL,2,17,9,16
AL,5,19,12,20
AL,4,18,11,19
VA,1,6,3,7,8,10
VA,2,4,5,6,9,11
! SOLID MASS ELEMENT
ET,1,186
!---MATERIAL MODEL
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,EX,1,,210e9
MPDATA,PRXY,1,,.3
TYPE, 1
MAT, 1
REAL, 0
ESYS, 0
SECNUM,
MAT, 1
REAL, 0
ESYS, 0
SECNUM,
ESIZE,0.0015,0,
MSHKEY, 1
TYPE, 1
MAT, 1
REAL,
ESYS, 0
SECNUM,
VMESH,1
VMESH,2
GPLOT
/SOL
! FIXED THE END OF THE BEAM
DA,7,ALL
!PRESURE LOAD ON THE OTHER END SURFACE DIRECTION DOWNWARD
SFA,11,1,PRES,150/(L2*W) ! we divide by (L2*W) to make the load constant even though the area is changing
/VIEW,1,1,1,1
/ANG,1
/REP,FAST
SOLVE
/post1
! GETTING THE VOLUME OF THE BEAM AND CREAT SV---TVOLUME
ETABLE, VOLUME, VOLU
SSUM
*GET,TVOLUME,SSUM,,ITEM,VOLUME
PLNSOL, eptt, EQV, 0, 1, ! THIS IS TO PLOT THE EQUV STRESS AND THEN STORE IT IN NEXT STEP
*GET, eqvstn, PLNSOL, 0, MAX, , , ! HERE TO STOR EQUV STRESS IN A VARIABLE CALLED EQVS
PLNSOL, S,EQV, 0,1.0 ! THIS IS TO PLOT THE NODAL EQUV STRESS AND THEN STORE IT IN NEXT STEP
*GET, eqvsts, PLNSOL, 0, MAX, , , ! HERE TO STOR EQUV STRESS IN A VARIABLE CALLED EQVS
PLESOL, S,EQV, 0,1.0 ! THIS IS TO PLOT THE ELEMENTS EQUV STRESS AND THEN STORE IT IN NEXT STEP
/IMAGE, save, beam-image, png, ! THIS IS TO SAVE IMAGE FILE NAMED beam-image.png
FINISH
*end
*use,beam-384
/opt
opanl,beam-384
OPVAR, H, DV, .002, .04
OPVAR, W, DV, .002, .03
OPVAR, eqvsts, SV, ,110e6 ! the allowable stress in an AISI 1018 steel component can be calculated to be R = UTS/FS = 440/4 = 110 MPa
OPVAR, TVOLUME, OBJ, , , 0.0000001 !THE VALUE OF OBJECTIVE function
OPTYP, SUBP
OPEXE
! LISTING ALL DESIGN SETS
OPLIST, ALL
!PLOT SOME RESULTS such as beam volume
PLVAROPT, TVOLUME
PLVAROPT, eqvsts
PLVAROPT, eqvstn ! Same behaviour as the equivalent stress because it is still in the elastic range
!plotting the beam width and height
PLVAROPT, W, H

 

Pin It